Un tub con cargas es bastante sencillo
Código:
[ITEMDEF i_tub_cargas]
ID=i_dye_tub
WEIGHT=10
VALUE=1
ON=@CREATE
MORE1=50 // Esto son las cargas iniciales, pon las que desees
COLOR=0 // Aquí pon los colores que quieras yo te pongo que salga sin color
NAME=Tub (50 Cargas) // Debes poner 50 o lo que pongas inicial en el more1, luego ya se encarga solo de restarlas
ON=@TARGON_Item
IF !(<SRC.TARG.CONT>==<SRC.FINDLAYER.21.UID>)
SRC.SYSMESSAGE El tub debe estar en tu mochila.
RETURN 1
ELSEIF (<MORE1> == 0)
SRC.SYSMESSAGE Parece que el tub se ha quedado sin cargas.
RETURN 1
ELSEIF (<SRC.TARG.TYPE>=t_clothing) || (<SRC.TARG.TYPE>=t_cloth) || (<SRC.TARG.TYPE>=t_cloth_bolt)
SRC.TARG.COLOR=<COLOR>
IF (<MORE1> == 1)
SRC.SYSMESSAGE El tub se ha quedado sin cargas!
MORE1=0
NAME=Tub (<EVAL <MORE1>> Cargas)
ELSE
MORE1=<MORE1>+-1
NAME=Tub (<EVAL <MORE1>> Cargas)
RETURN 1
ENDIF
ELSE
SRC.SYSMESSAGE Solo puedes pintar ropa!
RETURN 1
ENDIF
RETURN 1
Y esto un recargador por si te interesa también.
Código:
[ITEMDEF i_tub_recargador]
Name=Recargador de Tubs
ID=01008
WEIGHT=10
VALUE=1
ON=@CREATE
COLOR=0480
ON=@DCLICK
TARGET Que tub quieres recargar?
RETURN 1
ON=@TARGON_ITEM
IF (<SRC.TARG.BASEID>==i_tub_cargas) // Aquí deberás poner como has llamado al tub que quieres recargar
IF (<SRC.RESTEST 5000 i_gold>) // Esto indica si tienes 5 ks necesarios para recagarlo
SRC.CONSUME 5000 i_gold // Esto cobra 5 ks por cada recarga
SRC.TARG.MORE1=<SRC.TARG.MORE1>+1 // Añade una carga
SRC.TARG.NAME=Tub (<EVAL <SRC.TARG.MORE1>> Cargas)
SRC.SYSMESSAGE Has recargado el tub con exito!
ELSE
SRC.SYSMESSAGE Necesitas 5000 gps para poder recargar una carga!
ENDIF
ENDIF
RETURN 1
Para que un tub normal solo puedas pintar ropa te pongo esto
Código:
[ITEMDEF 0fab]
DEFNAME=i_dye_tub
TYPE=T_DYE_VAT
WEIGHT=10
CATEGORY=Items by Professions
SUBSECTION=Tailor
DESCRIPTION=Dying Tub
RESOURCES=5 i_log
SKILLMAKE=CARPENTRY 50.0, t_carpentry
//RESOURCES2=10 i_board
ON=@CREATE
name = Dye Tub
ON=@TARGON_Item
IF ( <SRC.TARG.CONT> != <SRC.FINDLAYER.21.UID> )
SRC.SYSMESSAGE El Tub debe estar en tu mochila.
RETURN 1
ELSEIF (<SRC.TARG.TYPE>=t_clothing) || (<SRC.TARG.TYPE>=t_cloth) || (<SRC.TARG.TYPE>=t_cloth_bolt)
SRC.TARG.COLOR=<COLOR>
ELSE
SRC.SYSMESSAGE Este tub solo sirve para ropa.
RETURN 1
ENDIF
RETURN 1
Prueba las dos cosas haber si funcionan bien